mirror of
https://github.com/pytorch/pytorch.git
synced 2025-10-20 12:54:11 +08:00
9875a834e4
# Motivation This PR is a part of RFC #114848, and it is a successor PR of #116249 and #116019. This PR would depend on oneDNN compilation in #116249. Some runtime support is needed in #116019. Aten operators like `addmm`, `baddmm` is defined in `Blas.cpp` in `aten/src/ATen/native/mkldnn/xpu/`. Accompanied with these files provide core functionaliy, `BlasImpl.h`, `Utils.h` and other file provide basic utilities for them. For instance, `Utils.h` provide common memory descriptor query utils for `Matmul.h` and these utility function will also be used in other primitive, like `convolution`. `BlasImpl.h` is a header file that provide helper for handling shape info processing in matmul related operators. It would not only help basic GEMM operator like `addmm, baddmm` but also help fusion operators used in `torch.compile` like `linear_pointwise` in #117824. In next stage, we would continually complete the oneDNN support through enabling `matmul fusion` and `convolution` related code. Co-authored-by: xiaolil1 <xiaoli.liu@intel.com> Co-authored-by: lei,zhenyuan <zhenyuan.lei@intel.com> Pull Request resolved: https://github.com/pytorch/pytorch/pull/117202 Approved by: https://github.com/EikanWang, https://github.com/jgong5, https://github.com/malfet ghstack dependencies: #117098, #117112
78 lines
1.8 KiB
CMake
78 lines
1.8 KiB
CMake
# This will define the following variables:
|
||
# SYCL_FOUND : True if the system has the SYCL library.
|
||
# SYCL_INCLUDE_DIR : Include directories needed to use SYCL.
|
||
# SYCL_LIBRARY_DIR ：The path to the SYCL library.
|
||
# SYCL_LIBRARY : SYCL library fullname.
|
||
|
||
include(FindPackageHandleStandardArgs)
|
||
|
||
set(SYCL_ROOT "")
|
||
if(DEFINED ENV{SYCL_ROOT})
|
||
set(SYCL_ROOT $ENV{SYCL_ROOT})
|
||
elseif(DEFINED ENV{CMPLR_ROOT})
|
||
set(SYCL_ROOT $ENV{CMPLR_ROOT})
|
||
endif()
|
||
|
||
string(COMPARE EQUAL "${SYCL_ROOT}" "" nosyclfound)
|
||
if(nosyclfound)
|
||
set(SYCL_FOUND False)
|
||
set(SYCL_REASON_FAILURE "SYCL library not set!!")
|
||
set(SYCL_NOT_FOUND_MESSAGE "${SYCL_REASON_FAILURE}")
|
||
return()
|
||
endif()
|
||
|
||
# Find include path from binary.
|
||
find_file(
|
||
SYCL_INCLUDE_DIR
|
||
NAMES include
|
||
HINTS ${SYCL_ROOT}
|
||
NO_DEFAULT_PATH
|
||
)
|
||
|
||
# Find include/sycl path from include path.
|
||
find_file(
|
||
SYCL_INCLUDE_SYCL_DIR
|
||
NAMES sycl
|
||
HINTS ${SYCL_ROOT}/include/
|
||
NO_DEFAULT_PATH
|
||
)
|
||
|
||
# Due to the unrecognized compilation option `-fsycl` in other compiler.
|
||
list(APPEND SYCL_INCLUDE_DIR ${SYCL_INCLUDE_SYCL_DIR})
|
||
|
||
# Find library directory from binary.
|
||
find_file(
|
||
SYCL_LIBRARY_DIR
|
||
NAMES lib lib64
|
||
HINTS ${SYCL_ROOT}
|
||
NO_DEFAULT_PATH
|
||
)
|
||
|
||
# Find SYCL library fullname.
|
||
find_library(
|
||
SYCL_LIBRARY
|
||
NAMES sycl
|
||
HINTS ${SYCL_LIBRARY_DIR}
|
||
NO_DEFAULT_PATH
|
||
)
|
||
|
||
find_library(
|
||
OCL_LIBRARY
|
||
NAMES OpenCL
|
||
HINTS ${SYCL_LIBRARY_DIR}
|
||
NO_DEFAULT_PATH
|
||
)
|
||
|
||
if((NOT SYCL_INCLUDE_DIR) OR (NOT SYCL_LIBRARY_DIR) OR (NOT SYCL_LIBRARY))
|
||
set(SYCL_FOUND False)
|
||
set(SYCL_REASON_FAILURE "SYCL library is incomplete!!")
|
||
set(SYCL_NOT_FOUND_MESSAGE "${SYCL_REASON_FAILURE}")
|
||
return()
|
||
endif()
|
||
|
||
find_package_handle_standard_args(
|
||
SYCL
|
||
FOUND_VAR SYCL_FOUND
|
||
REQUIRED_VARS SYCL_INCLUDE_DIR SYCL_LIBRARY_DIR SYCL_LIBRARY
|
||
REASON_FAILURE_MESSAGE "${SYCL_REASON_FAILURE}")
|